69e5dc5c80
## Description <!-- Briefly describe what this PR does and why --> Adds a module to open coder workspaces in Antigravity. Redoing PR with icon included ## Type of Change - [X] New module - [ ] New template - [ ] Bug fix - [ ] Feature/enhancement - [ ] Documentation - [ ] Other ## Module Information <!-- Delete this section if not applicable --> **Path:** `registry/coder/modules/antigravity` **New version:** `v1.0.0` **Breaking change:** [ ] Yes [ ] No ## Testing & Validation - [X] Tests pass (`bun test`) - [X] Code formatted (`bun fmt`) - [ ] Changes tested locally ## Related Issues <!-- Link related issues or write "None" if not applicable --> --------- Co-authored-by: Atif Ali <atif@coder.com> Co-authored-by: Copilot <175728472+Copilot@users.noreply.github.com>
105 lines
2.5 KiB
HCL
105 lines
2.5 KiB
HCL
terraform {
|
|
required_version = ">= 1.0"
|
|
|
|
required_providers {
|
|
coder = {
|
|
source = "coder/coder"
|
|
version = ">= 2.5"
|
|
}
|
|
}
|
|
}
|
|
|
|
variable "agent_id" {
|
|
type = string
|
|
description = "The ID of a Coder agent."
|
|
}
|
|
|
|
variable "folder" {
|
|
type = string
|
|
description = "The folder to open in Antigravity IDE."
|
|
default = ""
|
|
}
|
|
|
|
variable "open_recent" {
|
|
type = bool
|
|
description = "Open the most recent workspace or folder. Falls back to the folder if there is no recent workspace or folder to open."
|
|
default = false
|
|
}
|
|
|
|
variable "order" {
|
|
type = number
|
|
description = "The order determines the position of app in the UI presentation. The lowest order is shown first and apps with equal order are sorted by name (ascending order)."
|
|
default = null
|
|
}
|
|
|
|
variable "group" {
|
|
type = string
|
|
description = "The name of a group that this app belongs to."
|
|
default = null
|
|
}
|
|
|
|
variable "slug" {
|
|
type = string
|
|
description = "The slug of the app."
|
|
default = "antigravity"
|
|
}
|
|
|
|
variable "display_name" {
|
|
type = string
|
|
description = "The display name of the app."
|
|
default = "Antigravity IDE"
|
|
}
|
|
|
|
variable "mcp" {
|
|
type = string
|
|
description = "JSON-encoded string to configure MCP servers for Antigravity. When set, writes ~/.gemini/antigravity/mcp_config.json."
|
|
default = ""
|
|
}
|
|
|
|
data "coder_workspace" "me" {}
|
|
|
|
data "coder_workspace_owner" "me" {}
|
|
|
|
locals {
|
|
mcp_b64 = var.mcp != "" ? base64encode(var.mcp) : ""
|
|
}
|
|
|
|
module "vscode-desktop-core" {
|
|
source = "registry.coder.com/coder/vscode-desktop-core/coder"
|
|
version = "1.0.1"
|
|
|
|
agent_id = var.agent_id
|
|
|
|
web_app_icon = "/icon/antigravity.svg"
|
|
web_app_slug = var.slug
|
|
web_app_display_name = var.display_name
|
|
web_app_order = var.order
|
|
web_app_group = var.group
|
|
|
|
folder = var.folder
|
|
open_recent = var.open_recent
|
|
protocol = "antigravity"
|
|
}
|
|
|
|
resource "coder_script" "antigravity_mcp" {
|
|
count = var.mcp != "" ? 1 : 0
|
|
agent_id = var.agent_id
|
|
display_name = "Antigravity MCP"
|
|
icon = "/icon/antigravity.svg"
|
|
run_on_start = true
|
|
start_blocks_login = false
|
|
script = <<-EOT
|
|
#!/bin/sh
|
|
set -eu
|
|
mkdir -p "$HOME/.gemini/antigravity"
|
|
echo -n "${local.mcp_b64}" | base64 -d > "$HOME/.gemini/antigravity/mcp_config.json"
|
|
chmod 600 "$HOME/.gemini/antigravity/mcp_config.json"
|
|
EOT
|
|
}
|
|
|
|
output "antigravity_url" {
|
|
value = module.vscode-desktop-core.ide_uri
|
|
description = "Antigravity IDE URL."
|
|
}
|
|
|